Using CoDeSys on Raspberry Pi to poll ModbusTCP slave data, and uplink by using LoRaWAN ATIM ACW-XB

Home Labs Stories Using CoDeSys on Raspberry Pi to poll ModbusTCP slave data, and uplink by using LoRaWAN ATIM ACW-XB

by Bruno QUEGUINEUR

ABOUT THIS STORY

Posted on Jan. 1, 2019

#Node #Application #Cayenne #Device #ATIM #ARM-N8-LW #Modbus #CoDeSys #myDevices #ACW-XB #TCP

Expert

2 Days

3 people like this

Contact author

Introduction

In this story, a Raspberry Pi is used as a PLC (Programmable Logic Controller).
Program inside Raspberry Pi is developped in ST language (Structured Text) with CoDeSys IDE.
ModbusTCP polling is used by Raspberry Pi (master) to read values (temperature, power consumption) from an IRIO (slave).
In IRIO, temperature is stored in IEEE format (2 Modbus registers) and power consumption is stored in one integer word (1 Modbus register).
Raspberry Pi uses a small ATIM LoRaWAN device (ACW-XB) to uplink data.
Payloads are uplinked to Cayenne myDevice server (via TTN) to be viewed.
For this purpose, payloads use Cayenne LPP format.

Raspberry Pi installation

Hardware installation

Connect Raspberry Pi to Xbee breakout board (VCC, GND, TX, RX) as shown on the following Fritzing breadboard view, and the following picture.

NB : The breakboard will be connected to ATIM ACW-XB later.

Insert the Raspberry Pi in the case.

Drill a hole through the hat of the case.

Install the antenna and the ATIM device.

Connect the Xbee breakout to the ATIM ACW-XB, and close the case.

Enable SSH service and Serial Port

Open a terminal session on the raspberry pi.

Execute the followwing command to enable SSH service

pi@piAtim:~ $ sudo raspi-config

Select "5 Interfacing Options Configure connections to peripheral"

Then select "P2 SSH Enable/Disable remote command line"

Answer "Yes" to the question "Would you like the SSH server to be enabled? "

SSH is now enabled

Select "P6 Serial Enable/Disable shell and kernel"

Answer "No" to the question "Would you like a login shell to be accessible over serial?"

Answer "Yes" to the question "Would you like the serial port hardware to be enabled?"

Two messages confim that serial port is now configured :

"The serial login shell is disabled"

"The serial interface is enabled"

Test Uplink

Enter the following commands to setup communication baud-rate and send a test message to the ATIM ACW-XB :

pi@piAtim:~ $ sudo su
root@piAtim:/home/pi# stty -F /dev/ttyAMA0 19200
root@piAtim:/home/pi# echo test > /dev/ttyAMA0

The payload "746573740D0A" corresponding to ASCII payload "test\r\n" should appear on TTN account :

Cayenne LPP payload

Create a new program "PLC_LoRaWAN"

Program header :

PROGRAM PLC_LoRaWAN
VAR
	temperature:REAL; // °C
	pt:POINTER TO WORD; // pointer to IEEE temperature for little endian conversion
	lppTemperature,lppConsumption:INT; // values in Cayenne LPP format
	buf:ARRAY[0..7]OF BYTE; // LoRaWAN payload to be uplinked
END_VAR

Program body :

// temperature
pt:= ADR(temperature);
pt[0]:=SHR(mbTemperature[0],8)+SHL(mbTemperature[0],8); // reverse bytes order in first modbus word
pt[1]:=SHR(mbTemperature[1],8)+SHL(mbTemperature[1],8); // reverse bytes order in second modbus word
lppTemperature:=REAL_TO_INT(temperature*10); // Cayenne LPP : 0.1 °C
buf[0]:=01;  // channel number 1
buf[1]:=103; // Cayenne LPP data type for temperatures
buf[2]:=INT_TO_BYTE(SHR(lppTemperature,8)); // Cayenne LPP value (MSB)
buf[3]:=INT_TO_BYTE(lppTemperature);        // Cayenne LPP value (LSB)
// power consumption
lppConsumption:=mbConsumption*100; // Cayenne LPP : 0.01 for analog inputs
buf[4]:=02; // channel number 2
buf[5]:=02; // Cayenne LPP data type for analog input
buf[6]:=INT_TO_BYTE(SHR(lppConsumption,8)); // Cayenne LPP value (MSB)
buf[7]:=INT_TO_BYTE(lppConsumption);        // Cayenne LPP value (LSB)

Create a new Task associated to this new program "PLC_LoRaWAN"

Change periodicity to 30"

Upload the program and select "start" to execute the program.

Wait for 30" after debug has started... variable contents should appear...

Buf[] array contains a Cayenne LPP formated payload.

Send payload to TTN

On Raspberry Pi, a configuration file must be edited in order to use serial port from CoDeSys program.

Therefore, add 3 lines at the end of /etc/CODESYSControl.cfg :

pi@piAtim:~ $ sudo nano /etc/CODESYSControl.cfg
pi@piAtim:~ $ tail /etc/CODESYSControl.cfg
[SysCom]
Linux.Devicefile=/dev/ttyAMA
portnum := COM.SysCom.SYS_COMPORT1;

IMPORTANT : in this file, do not enter a zero after /dev/ttyAMA

SysCom library and SysTypes2 Interfaces are required to send data to serial port.

Add these 2 libraries to the project.

Create a function "sendFrame()" that will be called by the program to send data on the serial port.

Header :

FUNCTION sendFrame : BOOL
VAR_INPUT
	ptFrame: POINTER TO BYTE;
	length: UDINT;
END_VAR
VAR
	numPort : INT := 1;
	hCom,result: RTS_IEC_HANDLE;
	csComSettings: COM_Settings;
	written:UDINT;
END_VAR

Body :

sendFrame:=FALSE;
// open serial
hCom := SysComOpen(sPort:= numPort , pResult:= ADR(result));
IF hCom = RTS_INVALID_HANDLE THEN RETURN; END_IF	
// configure serial
csComSettings.byParity := SYS_NOPARITY;
csComSettings.byStopBits := SYS_ONESTOPBIT;
csComSettings.sPort := numPort;//SYS_COMPORT1;
csComSettings.ulBaudrate := SYS_BR_19200;
csComSettings.ulBufferSize := 0;
csComSettings.ulTimeout := 1;
result := SysComSetSettings(hCom:= hCom, pSettings:= ADR(csComSettings) , pSettingsEx:= 0);
IF result = RTS_INVALID_HANDLE THEN RETURN; END_IF
// send serial
written := SysComWrite(hCom:= hCom,	pbyBuffer:= ptFrame,	ulSize:= length,	ulTimeout:= 100,	pResult:= ADR(result) );
IF written<>length THEN RETURN; END_IF
// close serial
SysComClose(hCom);
// return true
sendFrame:=TRUE;

Add a call to sendFrame() function at the end of PLC_LoRaWAN program :

sendFrame(ptFrame:=ADR(buf),length:=8);

Upload and run the program...

Each 30", PLC_LoRaWAN sends a frame to TTN.